if test -f /usr/share/doc/fzf/examples/completion.zsh &> /dev/null; then
    source /usr/share/doc/fzf/examples/completion.zsh
fi

ssh_ids=$(find "$HOME/.ssh" -type f -name "id*" | grep -v '\.pub')
if [[ "$ssh_ids" != "" ]]; then
    eval "$(ssh-agent -s)" &> /dev/null
    for id in $(echo $ssh_ids); do
        ssh-add "$id" &> /dev/null
    done
fi

HISTFILE=~/.histfile
HISTSIZE=SAVEHIST=100000000
setopt appendhistory autocd notify
setopt menu_complete
unsetopt beep
bindkey -v

autoload -Uz up-line-or-beginning-search
autoload -Uz down-line-or-beginning-search
zle -N up-line-or-beginning-search
zle -N down-line-or-beginning-search
bindkey '\eOA' up-line-or-beginning-search
bindkey '\e[A' up-line-or-beginning-search
bindkey '\eOB' down-line-or-beginning-search
bindkey '\e[B' down-line-or-beginning-search

export EDITOR="vim"

zstyle ':completion:*' completer _expand _complete _ignored _correct _approximate
zstyle ':completion:*' matcher-list '+' '+m:{[:lower:]}={[:upper:]}' '+m:{[:lower:][:upper:]}={[:upper:][:lower:]}' '+r:|[._-]=** r:|=** l:|=*'
zstyle :compinstall filename '~/.zshrc'
zstyle ':completion:*' ignored-patterns '*.class'

autoload -Uz compinit
compinit

# enable color support of ls and also add handy aliases
if [ -x /usr/bin/dircolors ]; then
    test -r ~/.dircolors && eval "$(dircolors -b ~/.dircolors)" || eval "$(dircolors -b)"
    alias grep='grep --color=auto'
    alias fgrep='fgrep --color=auto'
    alias egrep='egrep --color=auto'
fi

export PATH=~/.bin:$HOME/.dotnet:~/.local/bin:/usr/local/go/bin:$PATH

fignore=(o class swp)

function SetTtyColors() {
    echo -en "\e]P0""2c2d27" # black       1
    echo -en "\e]P1""f92672" # darkgrey    2
    echo -en "\e]P2""00aa00" # darkred     3
    echo -en "\e]P3""f92672" # red         4
    echo -en "\e]P4""4444aa" # darkgreen   5
    echo -en "\e]P5""a6e22e" # green       6
    echo -en "\e]P6""f59762" # brown       7
    echo -en "\e]P7""fdfff1" # yellow      8
    echo -en "\e]P8""f92672" # darkblue    9
    echo -en "\e]P9""f92672" # blue        10
    echo -en "\e]PA""55ff55" # darkmagenta 11
    echo -en "\e]PB""f92672" # magenta     12
    echo -en "\e]PC""66d9ef" # darkcyan    13
    echo -en "\e]PD""ae81ff" # cyan        14
    echo -en "\e]PE""a1efe4" # lightgray   15
    echo -en "\e]PF""fdfff1" # white       16
    clear
}

if [ "$TERM" = "linux" ]; then
    SetTtyColors
fi

source ~/.shell_aliases
source ~/.zsh_local

function dconf-dump {
    local current_section=""
    local ignore_section=false
    # Ignores certain values/sections that shouldn't be synced
    dconf dump / | while read -r line; do
        if [[ "$line" == "["* ]]; then
            current_section="$line"
            ignore_section=false
        fi
        case "$current_section" in
            "[org/gnome/desktop/background]" | \
            "[org/gnome/shell/extensions/gsconnect"*)
                ignore_section=true
                ;;
            "[org/gnome/desktop/interface]")
                if [[ "$line" == "gtk-theme='"* ]]; then
                    continue
                fi
                echo "$line"
                ;;
            *)
                if ! $ignore_section; then
                    echo "$line"
                fi
                ;;
        esac
    done
}

function push-dconf {
    if ! command -v scpace &> /dev/null; then
        echo "An alias for scpace has not been defined on this device!"
        return 1
    fi
    dconf-dump > /tmp/dconf-dump || return 1
    scp -P 11275 /tmp/dconf-dump 'sage@sagev.space:~/dconf-dump'
}

function push-extensions {
    if ! command -v gnome-extensions &> /dev/null; then
        echo "gnome-extensions is not installed!"
        return
    fi
    mv /tmp/gnome-extension-list /tmp/prev-gnome-extension-list &> /dev/null
    gnome-extensions list > /tmp/gnome-extension-list
    # If there is NO difference, skip scp
    if [[ "$1" != "--force" ]] && diff /tmp/gnome-extension-list /tmp/prev-gnome-extension-list &> /dev/null; then
        return
    fi
    scp -P 11275 /tmp/gnome-extension-list 'sage@sagev.space:~/gnome-extension-list'
}

function merge-hist {
    \diff --unified=9999999999999999 "$1" "$2" | tail -n +4 | sed 's/^.//'
}

function sync-history {
    if ! scp -P 11275 'sage@sagev.space:~/histfile' "/tmp/.histfile"; then
        scp -P 11275 "$HOME/.histfile" 'sage@sagev.space:~/histfile'
        return
    fi
    merge-hist "$HOME/.histfile" "/tmp/.histfile" > "/tmp/$(whoami).histfile"
    mv "/tmp/$(whoami).histfile" "$HOME/.histfile"
    scp -P 11275 "$HOME/.histfile" 'sage@sagev.space:~/histfile'
}

function load-extensions {
    if ! command -v gnome-extensions &> /dev/null; then
        echo "gnome-extensions is not installed!"
        return
    fi
    scp -P 11275 'sage@sagev.space:~/gnome-extension-list' /tmp/gnome-extension-list
    local existing="$(gnome-extensions list)"
    for ext in $(cat /tmp/gnome-extension-list); do
        if grep "$ext" <(echo $existing) &> /dev/null; then
            continue
        fi
        VERSION_TAG=$(curl -Lfs "https://extensions.gnome.org/extension-query/?search=${ext}" | jq '.extensions[0] | .shell_version_map | map(.pk) | max')
        wget -O ${ext}.zip "https://extensions.gnome.org/download-extension/${ext}.shell-extension.zip?version_tag=$VERSION_TAG" || continue
        gnome-extensions install --force ${EXTENSION_ID}.zip
        if ! gnome-extensions list | grep --quiet ${ext}; then
            busctl --user call org.gnome.Shell.Extensions /org/gnome/Shell/Extensions org.gnome.Shell.Extensions InstallRemoteExtension s ${ext}
        fi
        gnome-extensions enable ${ext}
        rm ${EXTENSION_ID}.zip
    done
}

function pushdot {
    cd "$DOT_DIR" || return 1
    local res
    if [ $# -eq 0 ]; then
        git commit -a
        res="$?"
    else
        git commit -a -m "$@"
        res="$?"
    fi
    if [[ "$res" == "0" ]]; then
        git push -u origin main && push-extensions && sync-history && push-dconf
    fi
    cd -
    return $res 
}

function getdot {
    if ! command -v scpace &> /dev/null; then
        echo "An alias for scpace has not been defined on this device!"
        return 1
    fi
    cd "$DOT_DIR" || return 1
    git pull && ./copy.sh

    load-extensions
    sync-history

    rm /tmp/dconf-dump &> /dev/null
    scp -P 11275 'sage@sagev.space:~/dconf-dump' /tmp/dconf-dump
    dconf-dump > /tmp/current-dconf-dump
    if ! git --no-pager diff --no-index /tmp/current-dconf-dump /tmp/dconf-dump &> /dev/null; then
        echo
        echo "Incoming conf changes:"
        echo
        git --no-pager diff --no-index /tmp/current-dconf-dump /tmp/dconf-dump
        echo
        bash -c 'read -p "Press enter to continue, or Ctrl-C to cancel."' || return 1
        echo "Applying changes..."
    fi
    dconf load / < /tmp/dconf-dump || return 1
    cd - > /dev/null
}

if which starship &> /dev/null; then
    eval "$(starship init zsh)"
fi

last_get_file="/tmp/.$(whoami)-dotfiles-last-get"
current_date="$(date '+%Y-%m-%d')"
if test -d "$DOT_DIR" && [[ "$current_date" != "$(cat "$last_get_file")" ]] &> /dev/null; then
    echo "$current_date" > "$last_get_file"
    getdot
fi

export nvm_loaded=false

alias nvm="load_nvm; nvm"
alias node="load_nvm; node"

function load_nvm {
    if $nvm_loaded; then
        return
    fi
    unalias nvm
    unalias node
    export NVM_DIR="$HOME/.nvm"
    [ -s "$NVM_DIR/nvm.sh" ] && \. "$NVM_DIR/nvm.sh"  # This loads nvm
    [ -s "$NVM_DIR/bash_completion" ] && \. "$NVM_DIR/bash_completion"  # This loads nvm bash_completion
    export nvm_loaded=true
}

test -f /usr/share/zsh-syntax-highlighting/zsh-syntax-highlighting.zsh && source /usr/share/zsh-syntax-highlighting/zsh-syntax-highlighting.zsh
test -f "$HOME/.asdf/asdf.sh" && . "$HOME/.asdf/asdf.sh"
test -f ~/.cargo/env && source ~/.cargo/env